1、Asc(string) 函数

Asc 函数用于提取字 string 第一个字母的 ANSI 字符码，返回值：英文>0，中文<0（不适用于UTF-8编码）。

<%
response.write Asc("0")     '结果为：48
response.write Asc("a")     '结果为：97
response.write Asc("中")    'UTF-8中文结果始终为：1，GB2321中文结果为：-10544
%>

如果 string 为 Empty ，则产生一个实时错误。

 

2、AscB(string) 函数

AscB 函数用于提取字 string 第一个字节，返回值是Byte字类

<% 
response.write AscB("0")	'结果为：48 
response.write AscB("a")	'结果为：97 
response.write AscB("中")	'结果为：45
%> 

如果 string 为 Empty ，则产生一个实时错误。

 

3、AscW(string) 函数

AscW 函数用于提取字string第一个字母的Unicode字符码，返回值：英文>0，中文>255（适用UTF-8编码），不识别<0

<% 
response.write AscW("0")	'结果为：48 
response.write AscW("a")	'结果为：97 
response.write AscW("中")	'结果为：20013
%> 

如果 String 为 Empty ，则产生一个实时错误。

 

4、InStr( [start, ] source ,  token [, compare]  ) 函数

InStr 函数用于返回查找字符串 token 在源字符串 source 中的首字母位置。

source	源字符串
token	需查找的字符串
start	查找的起始位置，即从第几个字符开始查找。可选参数，默认为 1。  如果指定了 compare 参数，则一定要有 start 参数，如果 start 为 Null，将发生错误。
compare	匹配模式。可选参数，默认为 0。  0 表示二进制比较，1 表示忽略大小写的文本比较。

使用示例：

<%
response.write InStr("Bekda","b")	'结果为：0，默认二进制比较，区分大小写
response.write InStr(1,"Bekda","b",1)	'结果为：1，执行文本比较，忽略大小写
response.write InStr("Bekda","kda")	'结果为：3
response.write InStr(4,"BekdaBekda","Kda",1)	'结果为：8，从第4位开始执行文件比较
%>

5、InStrB( [start, ] source , token) 函数

InStrB 函数是 InStr 函数的字节版，用于返回查找字符串 token 在源字符串 source 中的首字节位置。

InStrB 是区分大小写的，它将源字符串当作一组字节来对待。

<%
response.write InStrB("Bekda","b")	'结果为：0，文本区分大小写
response.write InStrB("Bekda","B")	'结果为：1
response.write InStrB("Bekda","kda")	'结果为：5，一个字符占2个字节
response.write InStrB(8,"BekdaBekda","kda")	'结果为：15，一个字符占2个字节
response.write InStrB("贝加达","加")	'结果为：3，一个字符占2个字节
%>

 

6、LCase(string) 函数

LCase 函数用于将 string 转换为小写形式。

<%
response.write LCase("Bekda")	'结果为：bekda
response.write LCase("BEKDA")	'结果为：bekda
%>

7、UCase(string) 函数

UCase 函数用于将 string 转换为大写形式。

<%
response.write UCase("Bekda")	'结果为：BEKDA
response.write UCase("bekda")	'结果为：BEKDA
%>

 

8、Left(string, length) 函数

Left 函数用于从 string 起始处提取指定数目的字符，length 为提取的字符数目（数值型表达式）。

<%
response.write Left("Bekda",0)	'结果为：空
response.write Left("Bekda",2)	'结果为：Be
%>

 

9、LeftB(string, length) 函数

LeftB 函数用于从字符串的起始处提取指定数目的字节，length 为提取的字节数目（数值型表达式）。

<%
response.write LeftB("Bekda",0)	'结果为：空
response.write LeftB("Bekda",2)	'结果为：B
%>

 

10、Right(string, length) 函数 
Right 函数用于从 string 尾部提取指定数目的字符，length 为提取的字符数目（数值型表达式）。

<%
response.write Right("Bekda",0)	'结果为：空
response.write Right("Bekda",2)	'结果为：da
%>

11、RightB(string, length) 函数

RightB 函数用于从 string 尾部提取指定数目的字节，length 为提取的字节数目（数值型表达式）。

<%
response.write RightB("Bekda",0)	'结果为：空
response.write RightB("Bekda",2)	'结果为：a
%>

 

12、Mid(string , start [,length] ) 函数 

Mid 函数用于从字符串的某个位置开始提取指定数目的字符。

string是要从中提取字符的表达式，start是提取字符的起始位置，length 为提取的字符数目（数值型表达式）。

<%
response.write Mid("Bekda",1,2)	'结果为：Be
response.write Mid("Bekda",3)	'结果为：kda
%>

13、MidB(string , start  [,length] ) 函数

MidB 函数用于从字符串的某个位置开始提取指定数目的字节。

string是要从中提取字节的表达式，start是提取字节的起始位置，length 为提取的字节数目（数值型表达式）。

<%
response.write MidB("Bekda",1,2)	'结果为：B，一个字符占两个字节
response.write MidB("Bekda",3)	'结果为：ekda，一个字符占两个字节
response.write MidB("Bekda",4)	'结果为：乱码
%>

14、Len(string | varname) 函数

Len 函数用于返回字符串的大小或存储这个变量需要多少字符。

string 是任意有效的字符串表达式，varname 是变量名。

<%
response.write Len("Bekda")	'结果为：5
%>

 

15、LenB(string | varname) 函数

Len 函数用于返回字符串的字节大小或存储这个变量需要多少字节。

string 是任意有效的字符串表达式，varname 是变量名。

<%
response.write LenB("Bekda")	'结果为：10，一个字符占两个字节
%>

16、LTrim(string) 函数

LTrim 函数用于清除 string 左边的空格。

<%
response.write LTrim("  Bekda")	'结果为：Bekda（左侧无空格）
%>

 

17、RTrim(string) 函数

RTrim 函数用于清除 string 右边的空格。

<%
response.write RTrim("Bekda   ")	'结果为：Bekda（右侧无空格）
%>

 

18、Trim(string) 函数

Trim 函数用于清除 string 左右两边（首尾）的空格。

<%
response.write Trim("   Bekda   ")	'结果为：Bekda（左、右侧均无空格）
%>

 

19、String(number, character) 函数

String 函数用于构造含有多个相同字符的字符串。

number是返回字符串的长度，character是用来构造返回字符串的字符码（单字符，非字符串）。

<%
response.write String(4,"Bekda")	'结果为：BBBB
response.write String(6,"B")	'结果为：BBBBBB
%>

 

20、StrReverse(string) 函数
StrReverse函数用于颠倒 string 字符串的字符顺序。
如果 string 是零长度字符串 ("")，则会返回零长度字符串。如果 string 是 Null，则会发生错误

<%
Response.Write StrReverse("Bekda")	'结果为: adkeB
%>

21、StrComp(string1 , string2  [,compare] ) 函数
StrComp 函数返回 string1 字符串与 string2 字符串的比较结果。

compare 为可选参数，指定字符串匹配模式：0 表示二进制比较（默认值），1 表示忽略大小写的文本比较。

StrComp 函数有下列返回值：

string1 < string2	返回-1
string1 = string2	返回0
string1 > string2	返回1
string1 或 string2 为 Null	返回Null

使用示例：

<%
response.write StrComp("bekda","BEKDA")	'结果为：1，区分大小写
response.write StrComp("BEKDA","bekda")	'结果为：-1，区分大小写
response.write StrComp("Bekda","Bekda")	'结果为：0
response.write StrComp("Bekda","bekda",1)	'结果为：0，忽略大小写
%>

 

22、Replace(string ,find ,replacewith [,start] [,count] [,compare] ) 函数

Replace 函数用于将“string 字符串”中的“find 子字符串”替换为“replacewith 字符串”。 

string	原字符串（可以是字符串表达式）。
find	需要被替换的子字符串。
replacewith	用于替换的字符串。
start	返回结果的开始位置（函数返回从 start 位置开始的字符串，start 位置前面的字符串将被舍弃）。  可选参数，默认是 1。
count	执行子字符串替换的次数。  可选参数，默认值为 -1，表示进行所有可能的替换。  如果指定了 count 参数，则一定要有 start 参数
compare	匹配模式（字符串比较类型），0 表示二进制比较，1 表示忽略大小写的文本比较。。  可选参数，默认为 0。  如果指定了 compare 参数，则一定要有 start 参数 及 count 参数。

Replace 函数有下列返回值： 

string 为零长度	零长度字符串 ("")。
string 为 Null	错误。
find 为零长度	string 副本。
replacewith 为零长度	删除 所有 find 字符串后的 string 副本。
start > Len(string)	零长度字符串 ("")。
count 为 0	string 副本。

使用示例：

<%
Response.Write Replace("be_kda" , "be_" , "Be")	'结果为: Bekda
Response.Write Replace("be_kda - bE_kda" , "be_" , "Be" )	'结果为: Bekda - bE_kda，区分大小写
Response.Write Replace("be_kda - be_kda" , "be_" , "Be" , 4)	'结果为: kda - Bekda，从第4个字符位置开始
Response.Write Replace("be_k - be_k - be_k" , "be_" , "Be" , 1 , 2)	'结果为: Bek - Bek - be_k，执行2次替换
Response.Write Replace("be_k - bE_k - bE_k" , "be_" , "Be" , 1 , -1 , 1)	'结果为: Bek - Bek - Bek，忽略大小写
%>

 

23、Split(string [,delimiter] [,limit] [,compare] ) 拆分函数

Split 函数用于按分隔符 delimiter 折分 string 字符串，函数返回一个下标从0开始的一维数组。 

string	包含字符串和分隔符的字符串表达式。  如果 string 为零长度字符 ("")，Split 返回空数组，即不包括任何元素和数据的数组。
delimiter	分隔字符（字符串）。可选参数，默认值为：空格符（" "）。  如果 delimiter 为零长度字符 ("")，Split 函数返回只包含1个元素，数据为 string 的数组。
limit	拆分的数组元素数目（将 string 按 delimiter 拆分为指定元素数目 limit 的数组）；  可选参数，默认值为：-1，不指定拆分元素数目。
compare	分隔字符（字符串）匹配模式：0 表示二进制比较，1 表示忽略大小写的文本比较。   可选参数，默认值为：0，二进制比较区分大小写。

使用示例：

<%
dim Str,Are,i

'例1，结果：b|e|k|d|a|，分隔符为空，默认空格
Str="b e k d a"
Are=Split(Str)
for i=0 to Ubound(Are)
   Response.Write Are(i)&"|"
next

'例2，结果b|e|k|d|a|，分隔符为逗号
Str="b,e,k,d,a"
Are=Split(Str , ",")
for i=0 to Ubound(Are)
   Response.Write Are(i)&"|"
next

'例3，结果b|e|k,d,a|，拆分为3个字符串
Str="b,e,k,d,a"
Are=Split(Str , "," , 3)
for i=0 to Ubound(Are)
   Response.Write Are(i)&"|"
next

'例4，结果0A0A0A0A0|，分隔符默认区分大小写
Str="0A0A0A0A0"
Are=Split(Str , "a")
for i=0 to Ubound(Are)
   Response.Write Are(i)&"|"
next

'例5，结果0|0|0|0|0|，分隔符忽略分大小写
Str="0A0A0A0A0"
Are=Split(Str , "a" , -1 , 1)
for i=0 to Ubound(Are)
   Response.Write Are(i)&"|"
next
%>

 

24、Join(sourcearray [, delimiter]  ) 连接函数

Join 函数用于将一维数组所有元素通过连接字符(字符串) delimiter 连接成一个字符串。

sourcearray	一维数组，包含要联接的子字符串
delimiter	连接字符。可选参数，默认值为：空格（" "）。  如果 delimiter 是一个零长度字符串 ("")，Jion 将不使用分隔符而直接连接数组所有元素。

使用示例：

<%
dim Are(4)
    Are(0)="B"
    Are(1)="e"
    Are(2)="k"
    Are(3)="d"
    Are(4)="a"
Response.Write Join(Are)   '结果：B e k d a，连接符为空，默认空格
Response.Write Join(Are , ",")   '结果：B,e,k,d,a，连接符为逗号
%>